% Ray tracer article


input boxes

scale := 1;

marksize=4pt;
angle_radius=8pt;

def draw_mark(expr p, a) =
  begingroup
  save t, dm; pair dm;
  t = arctime a of p;
  dm = marksize*unitvector direction t of p
    rotated 90;
  draw (-.5dm.. .5dm) shifted point t of p;
  endgroup
enddef;

def draw_marked(expr p, n) =
  begingroup
  save amid;
  amid = .5*arclength p;
  for i=-(n-1)/2 upto (n-1)/2:
    draw_mark(p, amid+.6marksize*i);
  endfor
  draw p;
  endgroup
enddef;

def mark_angle(expr a, b, c, n) =
  begingroup
  save s, p; path p;
  p = unitvector(a-b){(a-b)rotated 90}..unitvector(c-b);
  s = .9marksize/length(point 1 of p - point 0 of p);
  if s<angle_radius: s:=angle_radius; fi
  draw_marked(p scaled s shifted b, n);
  endgroup
enddef;

def mark_rt_angle(expr a, b, c) =
  draw ((1,0)--(1,1)--(0,1))
       zscaled (angle_radius*unitvector(a-b)) shifted b
enddef;

% 7=G-for-geometry
beginfig(7);
  raylen = 4in;
  xpos = .2in;
  ypos = .2in;
  va = 45;    % view angle 
  pair p;
  p = (xpos, ypos);

%  sd = 1in;   % distance from p to screen
  sd = .20;     % Relative distance of screen between p and endlos
  facing = 15;  % degrees

  pair endlos;
  endlos = (raylen * cosd (facing), raylen * sind (facing));

  pair sm, sl, sr;
  sm  = sd[p,endlos]; %  + (sd * cosd (facing), sd * sind (facing));
  sl = sm + (tl * cosd (facing+90), tl * sind (facing+90));
  sl = p + (rl * cosd(facing+va), rl * sind(facing+va));
  sr = sm + (tr * cosd (facing-90), tr * sind (facing-90));
  sr = p + (rr * cosd(facing-va), rr * sind(facing-va));

  dotlabel.llft(btex P etex, (xpos, ypos));
  dotlabel.urt(btex $S_l$ etex, sl);
  dotlabel.rt(btex $S_r$ etex, sr);
%  dotlabel("", sm);
  drawarrow p -- endlos;
  draw sl -- sm -- sr;
  draw  sl -- p -- sr dashed withdots;
  mark_rt_angle(p, sm, sl);
  mark_angle(sr, p, sl, 1);

  pair anglelabel;
  anglelabel = p + (angle_radius * cosd(facing), angle_radius * sind(facing));
  label.urt(btex a etex, anglelabel);

  pair loslabel;
  loslabel = .8[p,endlos];
  label.lrt(btex {\rm Line of Sight} etex, loslabel);

  pair sdlabel;
  sdlabel = (1/2)[p,sm];
  label.bot(btex d etex, sdlabel);

  pair slabel;
  slabel = (1/2)[sl,sm];
  label.rt(btex \vbox{\hbox{View}\hbox{Plane}} etex, slabel);
endfig  ;

% Wall is behind you
beginfig(1);
  begingroup;
  pair p;
  p = (1in, 1in);
  numeric xmin, xmax, ymax;

  xmin = 0in;
  xmax = 2in;
  ymax = 2in;

  pair ll, lr, m;
  ll = (.2in, 0.6in);
  lr = (1.2in, 0.8in);
  m  = (1.6in, 1.8in);

  draw ll -- lr;
  dotlabel("", ll);
  dotlabel("", lr);

  dotlabel.bot("You", p);

  pair missed;
  numeric missed.x, missed.y;
  missed = p + t * (m - p);  % From p through m
  missed.y = ymax;
  drawarrow p -- m;

  pair bl, br;
  bl = ll + t2 * (lr - ll);  % From ll through lr
  br = ll + t3 * (lr - ll);  % From ll through lr
  bl = (xmin, x2);
  br = (xmax, x3);
  draw bl -- ll dashed withdots;
  draw lr -- br dashed withdots;

  pair loslabel;
  loslabel = .3[p,m];
%  label.rt(btex \vbox{\hbox{Line of}\hbox{Sight}} etex, loslabel);
  label.lrt(btex {Line of Sight} etex, loslabel);

  pair walllabel;
  walllabel = .5[ll,lr];
  label.bot(btex Wall etex, walllabel);
  endgroup;
endfig;

% LOS misses wall
beginfig(2);
  pair p;
  p = (1in, 1in);
  numeric xmin, xmax, ymax;

  xmin = 0in;
  xmax = 2in;
  ymax = 2in;

  pair ll, lr, m;
  ll = (.2in, 1.2in);
  lr = (1.2in, 1.4in);
  m  = (1.6in, 1.8in);

  draw ll -- lr;
  dotlabel("", ll);
  dotlabel("", lr);

  dotlabel.bot("You", p);

  pair missed;
  numeric missed.x, missed.y;

  missed = p + t * (m - p);  % From p through m
  missed.y = ymax;
  drawarrow p -- m;

  pair bl, br;
  bl = ll + t2 * (lr - ll);  % From ll through lr
  br = ll + t3 * (lr - ll);  % From ll through lr
  bl = (xmin, x2);
  br = (xmax, x3);
  draw bl -- ll dashed withdots;
  draw lr -- br dashed withdots;

  pair loslabel;
  loslabel = .3[p,m];
%  label.rt(btex \vbox{\hbox{Line of}\hbox{Sight}} etex, loslabel);
  label.lrt(btex {Line of Sight} etex, loslabel);

  pair walllabel;
  walllabel = .5[ll,lr];
  label.top(btex Wall etex, walllabel);
endfig;


% Overhead view of demo.ps
beginfig(4);
%  realwidth = 320pt;  % Width of other picture
  realwidth = 3in;
  s = realwidth/12;
  ht = 8;
  wd = 12;
  pair ulc, urc, lrc, llc;
  ulc = s*(0,ht);  urc = s*(wd,ht);
  llc = s*(0,0);   lrc = s*(wd,0);
  draw llc -- ulc -- urc -- lrc -- llc dashed evenly; % Frame

  pair pa, pb, pc, pd, pe, pf, pg, ph;
  pa = s*(0,4);
  pb = s*(1,4);
  pc = s*(3,8);
  pd = s*(4,8);
  pe = s*(5.75, 2.75);
  pf = s*(12, 2.75);
  pg = s*(2,6);
  ph = s*(2.5,2.5);
  draw pa -- pb -- pc; % LH object
  draw pg -- ph; % Thing that sticks out of LH object
  draw pd -- pe -- pf; % RH object

  pair you;
  you = s * (wd/3, 0);
  dotlabel.bot("You", you);
  draw you -- s*(0,ht/2) dashed withdots;  % View field 
  draw you -- s*(wd, ht) dashed withdots;  % Ditto
endfig;

end